可以直接应用于processing的一些JAVA函数1

    processing是基于JAVA的，所以，JAVA的一些函数可以直接应用，这实现了很多P5无法实现的效果，等于我们提前给P5“升级”了。

    这篇帖子算是笔记形式的，我将陆续添加，有遗落，请补充。

1.Frame
    Frame函数用于控制程序窗口

    a.运行过程中改变窗口尺寸
void setup (){  
  size(400,300);
  frame.setResizable(true); //允许改变程序窗口
}
void draw(){  
  rect(width/4,height/4,width/2,height/2);//根据窗口尺寸创建一个矩形
  println(height);
}

    b.修改窗口标题
       P5程序窗口标题与源文件文件名一致，发布成exe后，修改exe文件名也不能改变既有的标题。而源文件文件名是不支持中文的，但我们可以用Frame的setTitle函数自定义标题----甚至中文标题，并且还能动态调整。
void setup (){ 
  size(400,300);
  frame.setTitle("锐梵互动") ;
}

---------------------------------------------------------------------------------------

String[] name = {"锐","锐梵","锐梵互","锐梵互动","www.burncg.cn"};
int num=0;
void setup (){ 
  size(400,300);
}
void draw()
{
  frame.setTitle(name[num]) ;
  if(num<name.length-1){
    num++;
  }
  else{
    num=0;
  }
  delay(1000);
}

2.Robot
   Robot函数可以提供对鼠标和键盘的控制，还能捕获桌面图像。

   a.控制鼠标位置
//注意！鼠标被控后可按“esc”键退出程序，别说我没告诉你！
Robot robby;
void setup(){
  size(500, 500);
  try  {  
    robby = new Robot(); 
  } 
  catch (AWTException e)  {
    println("Robot class not supported by your system!");  
    exit(); 
  }
}
void draw(){ 
  robby.mouseMove(int(random(100))+400,int(random(100))+400);
}

    b.捕获桌面图像
PImage a;
Rectangle irect;//创建一个矩形对象用于指定捕捉范围
Robot robby;
void setup(){
  size(500, 500);
  try  {  
    robby = new Robot(); 
  } 
  catch (AWTException e)  {
    println("Robot class not supported by your system!");  
    exit(); 
  }
  irect=new Rectangle(500,500);
  a=new PImage(robby.createScreenCapture(irect));
  image(a,0,0);
}
void draw(){ 
}

 

未完待续

[本日志由 admin 于 2010-01-19 04:28 PM 编辑]
文章来自: 本站原创
引用通告: 查看所有引用 | 我要引用此文章
Tags:
相关日志: